» Clipper » Linking Date and Application Version



Linking Date and Application Version

How can I put a stamp of linking date and application version in the executables?? I always put the date and time of linking, application and database version number. To do this, I utilize Blinker's feature of embedding serial number into the executables directly. Please read my link script and source code thoroughly, as follows:

 
// Make script
app.exe: main.obj etc.obj
  dInfo 1.01 #030
  blinker @app @dInfo
 
 
// Source code to generate dInfo.lnk
function dInfo( _cLinkVersion, _cDBFversion )
  local hnd
 
  default _cLinkVersion to "0.01", _cDBFversion to "#001"
 
  hnd := fCreate( "dInfo.lnk" )
  if hnd > 0
    fWrite( hnd, "blinker executable serial " + ;
                  dToS( date() ) + " " + ;
                  subStr( time(), 1, 5 ) + " " + ;
                  padR( _cLinkVersion, 4 ) + " " + ;
                  padR( _cDBFversion, 4 ) )
    fClose( hnd )
    ? memoRead( "dInfo.lnk" )
  endif
return nil
 
 
// Source code to retrieve Date Linking and Version Number
static cBliSerNum, dLinkDate, cLinkTime, cLinkVersion, cDBFversion
 
init function __dInfo()
 
  cBliSerNum   := bliSerNum()
  dLinkDate    := stod( subStr( cBliSerNum, 1, 8 ) )
  cLinkTime    := subStr( cBliSerNum, 10, 5 )
  cLinkVersion := subStr( cBliSerNum, 16, 4 )
  cDBFversion  := subStr( cBliSerNum, 21, 4 )
return nil
 
function dInfoLinkDate()
return dLinkDate
 
function dInfoLinkTime()
return cLinkTime
 
function dInfoLinkVersion()
return cLinkVersion
 
function dInfoDBFversion()
return cDBFversion